NixOS-Config/flake.nix

{
  inputs = {
    # System inputs
    nixpkgs.url = "nixpkgs/nixos-24.05";
    unstable.url = "nixpkgs/nixos-unstable";
    hardware.url = "github:nixos/nixos-hardware/master";

    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.4.1";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    impermanence.url = "github:nix-community/impermanence";
    chaotic.url = "github:chaotic-cx/nyx/nyxpkgs-unstable";
    mailserver.url = "gitlab:simple-nixos-mailserver/nixos-mailserver/nixos-24.05";
    minecraft.url = "github:Infinidoge/nix-minecraft";

    # Home inputs
    home-manager = {
      url = "github:nix-community/home-manager/release-24.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nur.url = "github:nix-community/NUR";
    blender-bin.url = "https://flakehub.com/f/edolstra/blender-bin/1.0.9.tar.gz";
  };

  outputs = {
    nixpkgs,
    unstable,
    hardware,
    lanzaboote,
    disko,
    impermanence,
    chaotic,
    mailserver,
    minecraft,
    home-manager,
    nur,
    blender-bin,
    ...
  }:
  let
    mkNix = modules: nixpkgs.lib.nixosSystem {
      inherit modules;
      specialArgs = {
        inherit
          unstable
          hardware
          lanzaboote
	  disko
          impermanence
          chaotic
          mailserver
          minecraft
          home-manager
          nur
          blender-bin
          ;
      };
    };
    mkHome = modules: pkgs: home-manager.lib.homeManagerConfiguration {
      inherit modules pkgs;
      extraSpecialArgs = {
        inherit
          unstable
          nur
          blender-bin
          ;
      };
    };
  in {
    # nixos-rebuild switch --flake .#hostname
    nixosConfigurations = {
      firefly = mkNix [ ./hosts/firefly ]; # Main Desktop
      detritus = mkNix [ ./hosts/detritus/system ]; # Acer Desktop

      shuttle = mkNix [ ./hosts/shuttleworth/system ]; # Pinebook Pro
      lacros = mkNix [ ./hosts/lacros/system ]; # Dell Chromebook
      redmond = mkNix [ ./hosts/redmond/system ]; # Lenovo Laptop
      treefruit = mkNix [ ./hosts/treefruit/system ]; # Macbook Pro 14,1

      cyberspark = mkNix [ ./hosts/cyberspark/system ]; # Dell Optiplex 7010
      bomberman = mkNix [ ./hosts/bomberman/system ]; # Oracle ARM
    };

    # home-manager switch --flake .#username
    homeConfigurations."jimbo" = mkHome [ ./modules/home ] nixpkgs.legacyPackages.x86_64-linux;
  };
}