NixOS-Config/flake.nix

{
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-24.05";
    unstable.url = "nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager/release-24.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nur.url = "github:nix-community/NUR";
    blender-bin.url = "https://flakehub.com/f/edolstra/blender-bin/1.0.9.tar.gz";
    hardware.url = "github:nixos/nixos-hardware/master";

    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.4.1";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    mailserver.url = "gitlab:simple-nixos-mailserver/nixos-mailserver/nixos-24.05";
    minecraft.url = "github:Infinidoge/nix-minecraft";
  };

  outputs = { self, nixpkgs, unstable, home-manager, nur, blender-bin, hardware, lanzaboote, mailserver, minecraft, ... }:
  let
    mkNixos = modules: nixpkgs.lib.nixosSystem {
      inherit modules;
      specialArgs = { inherit nixpkgs unstable hardware lanzaboote mailserver minecraft; };
    };
    
    mkHome = modules: pkgs: home-manager.lib.homeManagerConfiguration {
      inherit modules pkgs;
      extraSpecialArgs = { inherit unstable nur blender-bin; };
    };
  in {
    # nixos-rebuild switch --flake .#hostname
    nixosConfigurations = {
      firefly = mkNixos [ ./hosts/firefly/system ];
      cyberspark = mkNixos [ ./hosts/cyberspark/system ];
      shuttleworth = mkNixos [ ./hosts/shuttleworth/system ];
    };

    # home-manager switch --flake .#username@hostname
    homeConfigurations = {
      "jimbo@firefly" = mkHome [ ./hosts/firefly/home ] nixpkgs.legacyPackages.x86_64-linux;
      "jimbo@cyberspark" = mkHome [ ./hosts/cyberspark/home ] nixpkgs.legacyPackages.x86_64-linux;
      "jimbo@shuttleworth" = mkHome [ ./hosts/shuttleworth/home ] nixpkgs.legacyPackages.aarch64-linux;
    };
  };
}