{
  inputs = {
    # System inputs
    nixpkgs.url = "nixpkgs/nixos-24.11";
    unstable.url = "nixpkgs/nixos-unstable";

    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.4.1";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    impermanence.url = "github:nix-community/impermanence";
    mailserver.url = "gitlab:simple-nixos-mailserver/nixos-mailserver/nixos-24.05";
    minecraft.url = "github:Infinidoge/nix-minecraft";

    # Home inputs
    home-manager = {
      url = "github:nix-community/home-manager/release-24.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nur.url = "github:nix-community/NUR";
    blender.url = "https://flakehub.com/f/edolstra/blender-bin/1.0.11.tar.gz";
  };

  outputs = {
    self,
    nixpkgs,
    unstable,
    lanzaboote,
    disko,
    impermanence,
    mailserver,
    minecraft,
    home-manager,
    nur,
    blender,
    ...
  }:
  let
    mkNix = modules: nixpkgs.lib.nixosSystem {
      inherit modules;
      specialArgs = {
        inherit
	  self
          unstable
          lanzaboote
	  disko
          impermanence
          mailserver
          minecraft
          home-manager
          nur
          blender
          ;
      };
    };
    mkHome = modules: pkgs: home-manager.lib.homeManagerConfiguration {
      inherit modules pkgs;
      extraSpecialArgs = {
        inherit
          unstable
          nur
          blender
          ;
      };
    };
  in {
    # nixos-rebuild switch --flake /etc/nixos#hostname
    nixosConfigurations = {
      tower = mkNix [ ./hosts/tower ]; # Main Desktop

      envy = mkNix [ ./hosts/envy ]; # HP Convertable
      axolotl = mkNix [ ./hosts/axolotl ]; # PineBook Pro
      lacros = mkNix [ ./hosts/lacros ]; # Dell Chromebook
      redmond = mkNix [ ./hosts/redmond ]; # Lenovo Dual-Boot
      extern = mkNix [ ./hosts/extern ]; # External Drive/USB

      kitty = mkNix [ ./hosts/kitty ]; # Dell Optiplex 7010
      prophet = mkNix [ ./hosts/prophet ]; # Oracle Neoverse-N1
    };

    # home-manager switch --flake /etc/nixos#username
    homeConfigurations."jimbo" = mkHome [ ./modules/home ] nixpkgs.legacyPackages.x86_64-linux;
  };
}