{
  inputs = {
    # System inputs
    nixpkgs.url = "nixpkgs/nixos-24.05";
    unstable.url = "nixpkgs/nixos-unstable";
    hardware.url = "github:nixos/nixos-hardware/master";

    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.4.1";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    impermanence.url = "github:nix-community/impermanence";
    mailserver.url = "gitlab:simple-nixos-mailserver/nixos-mailserver/nixos-24.05";
    minecraft.url = "github:Infinidoge/nix-minecraft";

    # Home inputs
    home-manager = {
      url = "github:nix-community/home-manager/release-24.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nur.url = "github:nix-community/NUR";
    blender-bin.url = "https://flakehub.com/f/edolstra/blender-bin/1.0.9.tar.gz";
  };

  outputs = {
    nixpkgs,
    unstable,
    hardware,
    lanzaboote,
    disko,
    impermanence,
    mailserver,
    minecraft,
    home-manager,
    nur,
    blender-bin,
    ...
  }:
  let
    mkNix = modules: nixpkgs.lib.nixosSystem {
      inherit modules;
      specialArgs = {
        inherit
          unstable
          hardware
          lanzaboote
	  disko
          impermanence
          mailserver
          minecraft
          home-manager
          nur
          blender-bin
          ;
      };
    };
    mkHome = modules: pkgs: home-manager.lib.homeManagerConfiguration {
      inherit modules pkgs;
      extraSpecialArgs = {
        inherit
          unstable
          nur
          blender-bin
          ;
      };
    };
  in {
    # nixos-rebuild switch --flake /etc/nixos#hostname
    nixosConfigurations = {
      firefly = mkNix [ ./hosts/firefly ]; # Main Desktop
      detritus = mkNix [ ./hosts/detritus ]; # Acer Desktop

      shuttle = mkNix [ ./hosts/shuttleworth ]; # Pinebook Pro
      lacros = mkNix [ ./hosts/lacros ]; # Dell Chromebook
      redmond = mkNix [ ./hosts/redmond ]; # Lenovo Dual-Boot Laptop
      treefruit = mkNix [ ./hosts/treefruit ]; # Macbook Pro 14,1
      leash = mkNix [ ./hosts/leash ]; # Portable Hard-Drive

      cyberspark = mkNix [ ./hosts/cyberspark ]; # Dell Optiplex 7010
      bomberman = mkNix [ ./hosts/bomberman ]; # Oracle ARM
    };

    # home-manager switch --flake /etc/nixos#username
    homeConfigurations."jimbo" = mkHome [ ./modules/home ] nixpkgs.legacyPackages.x86_64-linux;
  };
}