{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-24.05";
    unstable.url = "github:nixos/nixpkgs/nixos-unstable";
    nur.url = "github:nix-community/NUR";
    mailserver.url = "gitlab:simple-nixos-mailserver/nixos-mailserver/nixos-24.05";
    blender-bin.url = "https://flakehub.com/f/edolstra/blender-bin/1.0.8.tar.gz";
    minecraft.url = "github:Infinidoge/nix-minecraft";
    hardware.url = "github:nixos/nixos-hardware/master";

    # Secure boot
    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.4.1";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Home manager
    home-manager = {
      url = "github:nix-community/home-manager/release-24.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    unstable,
    nur,
    mailserver,
    blender-bin,
    hardware,
    lanzaboote,
    home-manager,
    ...
  } @inputs: let
    inherit (self) outputs;
    forAllSystems = nixpkgs.lib.genAttrs [
      "aarch64-linux" 
      "x86_64-linux"
    ];
  in rec {
    packages = forAllSystems (system: import ./packages nixpkgs.legacyPackages.${system});

    # Variables defined so they can be accessed globally
    secrets = import ./variables/secrets;
    cmd = import ./variables/cmd;
    displays = import ./variables/displays;
    ips = import ./variables/ips;
    look = import ./variables/look;
    ws = import ./variables/workspaces;

    # NixOS config entrypoint, use 'nixos-rebuild --flake .#your-hostname'
    nixosConfigurations = {
      firefly = nixpkgs.lib.nixosSystem {
        specialArgs = {inherit inputs outputs;};
        modules = [
          ./hosts/firefly/system
	  lanzaboote.nixosModules.lanzaboote
        ];
      };
      cyberspark = nixpkgs.lib.nixosSystem {
        specialArgs = {inherit inputs outputs;};
        modules = [
          ./system/hosts/JimServer/configuration.nix
	  mailserver.nixosModule
        ];
      };
      shuttleworth = nixpkgs.lib.nixosSystem {
        specialArgs = {inherit inputs outputs;};
        modules = [
          ./system/hosts/JimPine/configuration.nix
	  hardware.nixosModules.pine64-pinebook-pro
        ];
      };
    };

    # Home-manager configuration, use 'home-manager --flake .#your-username@your-hostname'
    homeConfigurations = {
      "jimbo@firefly" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages.x86_64-linux;
        extraSpecialArgs = {inherit inputs outputs;};
        modules = [
          ./home/hosts/JimDesktop/home.nix
	  nur.nixosModules.nur
        ];
      };
      "jimbo@cyberspark" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages.x86_64-linux;
        extraSpecialArgs = {inherit inputs outputs;};
        modules = [
          ./home/hosts/JimServer/home.nix
        ];
      };
      "jimbo@shuttleworth" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages.aarch64-linux;
        extraSpecialArgs = {inherit inputs outputs;};
        modules = [
          ./home/hosts/JimPine/home.nix
	  nur.nixosModules.nur
        ];
      };
      # Derivation for ssh envrionments on other people's servers
      "jimbo@JimTerminal" = home-manager.lib.homeManagerConfiguration {
        pkgs = nixpkgs.legacyPackages.x86_64-linux;
        extraSpecialArgs = {inherit inputs outputs;};
        modules = [
          ./home/hosts/JimTerminal/home.nix
        ];
      };
    };
  };
}